Metacat

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author: cjones $'

  *     '$Date: 2006-11-17 13:37:07 -0800 (Fri, 17 Nov 2006) $'

  * '$Revision: 3094 $'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-variable.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:import href="eml-literature.xsl"/>

  <xsl:output method="html" encoding="iso-8859-1"

    doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN"

    doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"

    indent="yes" />  

  <!-- This module is for coverage and it is self contained(It is a table

       and will handle reference by it self)-->

  <xsl:template name="coverage">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

          <table class="{$tabledefaultStyle}">

            <xsl:for-each select="geographicCoverage">

                <xsl:call-template name="geographicCoverage">

                </xsl:call-template>

            </xsl:for-each>

          </table>

          <table class="{$tabledefaultStyle}">

             <xsl:for-each select="temporalCoverage">

                <xsl:call-template name="temporalCoverage">

                </xsl:call-template>

            </xsl:for-each>

          </table>

          <table class="{$tabledefaultStyle}">

            <xsl:for-each select="taxonomicCoverage">

                <xsl:call-template name="taxonomicCoverage">

                </xsl:call-template>

            </xsl:for-each>

          </table>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <table class="{$tabledefaultStyle}">

            <xsl:for-each select="geographicCoverage">

                <xsl:call-template name="geographicCoverage">

                </xsl:call-template>

            </xsl:for-each>

          </table>

          <table class="{$tabledefaultStyle}">

            <xsl:for-each select="temporalCoverage">

                <xsl:call-template name="temporalCoverage">

                </xsl:call-template>

            </xsl:for-each>

          </table>

          <table class="{$tabledefaultStyle}">

            <xsl:for-each select="taxonomicCoverage">

                <xsl:call-template name="taxonomicCoverage">

                </xsl:call-template>

            </xsl:for-each>

          </table>

        </xsl:otherwise>

      </xsl:choose>

  </xsl:template>

 <!-- ********************************************************************* -->

 <!-- **************  G E O G R A P H I C   C O V E R A G E  ************** -->

 <!-- ********************************************************************* -->

  <xsl:template name="geographicCoverage">

    <xsl:choose>

      <xsl:when test="references!=''">

        <xsl:variable name="ref_id" select="references"/>

        <xsl:variable name="references" select="$ids[@id=$ref_id]" />

        <xsl:for-each select="$references">

          <xsl:for-each select="geographicCoverage">

            <table class="{$tabledefaultStyle}">

              <xsl:call-template name="geographicCovCommon" />

            </table>

          </xsl:for-each>

        </xsl:for-each>

      </xsl:when>

      <xsl:otherwise>

          <table class="{$tabledefaultStyle}">

            <xsl:call-template name="geographicCovCommon" />

          </table>

      </xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template name="geographicCovCommon">

      <tr>

        <th colspan="2">

          <xsl:text>Geographic Region:</xsl:text>

        </th>

      </tr>

      <xsl:apply-templates select="geographicDescription"/>

      <xsl:apply-templates select="boundingCoordinates"/>

      <xsl:for-each select="datasetGPolygon">

          <xsl:if test="datasetGPolygonOuterGRing">

            <xsl:apply-templates select="datasetGPolygonOuterGRing"/>

          </xsl:if>

          <xsl:if test="datasetGPolygonExclusionGRing">

              <xsl:apply-templates select="datasetGPolygonExclusionGRing"/>

          </xsl:if>

     </xsl:for-each>

  </xsl:template>

  <xsl:template match="geographicDescription">

    <tr>

      <td class="{$firstColStyle}">Geographic Description:</td>

      <td class="{$secondColStyle}"><xsl:value-of select="."/></td>

    </tr>

  </xsl:template>

  <xsl:template match="boundingCoordinates">

      <tr><td class="{$firstColStyle}">

           Bounding Coordinates:

          </td>

       <td>

         <table>

           <xsl:apply-templates select="westBoundingCoordinate"/>

           <xsl:apply-templates select="eastBoundingCoordinate"/>

           <xsl:apply-templates select="northBoundingCoordinate"/>

           <xsl:apply-templates select="southBoundingCoordinate"/>

           <xsl:apply-templates select="boundingAltitudes"/>

         </table>

      </td>

      </tr>

  </xsl:template>

  <xsl:template match="westBoundingCoordinate">

    <tr><td class="{$firstColStyle}">

         <xsl:text>West: &#160;</xsl:text>

        </td>

        <td class="{$secondColStyle}">

         <xsl:value-of select="."/>&#160; degrees

        </td>

     </tr>

  </xsl:template>

  <xsl:template match="eastBoundingCoordinate">

    <tr><td class="{$firstColStyle}">

       <xsl:text>East: &#160;</xsl:text>

       </td>

       <td class="{$secondColStyle}">

         <xsl:value-of select="."/>&#160; degrees

       </td>

     </tr>

  </xsl:template>

  <xsl:template match="northBoundingCoordinate">

    <tr><td class="{$firstColStyle}">

         <xsl:text>North: &#160;</xsl:text>

        </td>

        <td class="{$secondColStyle}">

          <xsl:value-of select="."/>&#160; degrees

        </td>

     </tr>

  </xsl:template>

  <xsl:template match="southBoundingCoordinate">

    <tr><td class="{$firstColStyle}">

         <xsl:text>South: &#160;</xsl:text>

       </td>

       <td class="{$secondColStyle}">

         <xsl:value-of select="."/>&#160; degrees

        </td>

    </tr>

  </xsl:template>

  <xsl:template match="boundingAltitudes">

      <tr><td class="{$firstColStyle}">

        Mimimum Altitude:</td><td class="{$secondColStyle}">

        <xsl:apply-templates select="altitudeMinimum"/></td></tr>

      <tr><td class="{$firstColStyle}">

        Maximum Altitude:</td><td class="{$secondColStyle}">

        <xsl:apply-templates select="altitudeMaximum"/></td></tr>

  </xsl:template>

  <xsl:template match="altitudeMinimum">

     <xsl:value-of select="."/> &#160;<xsl:value-of select="../altitudeUnits"/>

  </xsl:template>

  <xsl:template match="altitudeMaximum">

    <xsl:value-of select="."/> &#160;<xsl:value-of select="../altitudeUnits"/>

  </xsl:template>

  <xsl:template match="datasetGPolygonOuterGRing">

    <tr><td class="{$firstColStyle}">

          <xsl:text>G-Ploygon(Outer Ring): </xsl:text>

        </td>

        <td class="{$secondColStyle}">

           <xsl:apply-templates select="gRingPoint"/>

           <xsl:apply-templates select="gRing"/>

        </td>

     </tr>

  </xsl:template>

  <xsl:template match="datasetGPolygonExclusionGRing">

    <tr><td class="{$firstColStyle}">

          <xsl:text>G-Ploygon(Exclusion Ring): </xsl:text>

        </td>

        <td class="{$secondColStyle}">

           <xsl:apply-templates select="gRingPoint"/>

           <xsl:apply-templates select="gRing"/>

        </td>

     </tr>

  </xsl:template>

  <xsl:template match="gRing">

    <xsl:text>(GRing) &#160;</xsl:text>

    <xsl:text>Latitude: </xsl:text>

    <xsl:value-of select="gRingLatitude"/>,

    <xsl:text>Longitude: </xsl:text>

    <xsl:value-of select="gRingLongitude"/><br/>

  </xsl:template>

  <xsl:template match="gRingPoint">

    <xsl:text>Latitude: </xsl:text>

    <xsl:value-of select="gRingLatitude"/>,

    <xsl:text>Longitude: </xsl:text>

    <xsl:value-of select="gRingLongitude"/><br/>

  </xsl:template>

<!-- ********************************************************************* -->

<!-- ****************  T E M P O R A L   C O V E R A G E  **************** -->

<!-- ********************************************************************* -->

  <xsl:template name="temporalCoverage">

    <xsl:choose>

      <xsl:when test="references!=''">

        <xsl:variable name="ref_id" select="references"/>

        <xsl:variable name="references" select="$ids[@id=$ref_id]" />

        <xsl:for-each select="$references">

          <table class="{$tabledefaultStyle}">

            <xsl:call-template name="temporalCovCommon" />

          </table>

        </xsl:for-each>

      </xsl:when>

      <xsl:otherwise>

          <table class="{$tabledefaultStyle}">

            <xsl:call-template name="temporalCovCommon" />

          </table>

      </xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template name="temporalCovCommon" >

     <tr><th colspan="2">

      <xsl:text>Time Period:</xsl:text></th></tr>

      <xsl:apply-templates select="singleDateTime"/>

      <xsl:apply-templates select="rangeOfDates"/>

  </xsl:template>

  <xsl:template match="singleDateTime">

    <tr><td class="{$firstColStyle}">

            Date:

         </td>

         <td>

             <xsl:call-template name="singleDateType" />

         </td>

     </tr>

   </xsl:template>

  <xsl:template match="rangeOfDates">

     <tr><td class="{$firstColStyle}">

            Begin:

         </td>

         <td>

            <xsl:apply-templates select="beginDate"/>

          </td>

     </tr>

     <tr><td class="{$firstColStyle}">

            End:

          </td>

          <td>

             <xsl:apply-templates select="endDate"/>

          </td>

     </tr>

  </xsl:template>

  <xsl:template match="beginDate">

      <xsl:call-template name="singleDateType"/>

  </xsl:template>

  <xsl:template match="endDate">

      <xsl:call-template name="singleDateType"/>

  </xsl:template>

  <xsl:template name="singleDateType">

    <table>

     <xsl:if test="calendarDate">

      <tr>

       <td colspan="2" class="{$secondColStyle}">

          <xsl:value-of select="calendarDate"/>

          <xsl:if test="./time and normalize-space(./time)!=''">

            <xsl:text>&#160; at &#160;</xsl:text><xsl:apply-templates select="time"/>

          </xsl:if>

        </td>

      </tr>

     </xsl:if>

     <xsl:if test="alternativeTimeScale">

         <xsl:apply-templates select="alternativeTimeScale"/>

     </xsl:if>

    </table>

  </xsl:template>

  <xsl:template match="alternativeTimeScale">

        <tr><td class="{$firstColStyle}">

            Timescale:</td><td class="{$secondColStyle}"><xsl:value-of select="timeScaleName"/></td></tr>

        <tr><td class="{$firstColStyle}">

            Time estimate:</td><td class="{$secondColStyle}"><xsl:value-of select="timeScaleAgeEstimate"/></td></tr>

        <xsl:if test="timeScaleAgeUncertainty and normalize-space(timeScaleAgeUncertainty)!=''">

        <tr><td class="{$firstColStyle}">

            Time uncertainty:</td><td class="{$secondColStyle}"><xsl:value-of select="timeScaleAgeUncertainty"/></td></tr>

        </xsl:if>

        <xsl:if test="timeScaleAgeExplanation and normalize-space(timeScaleAgeExplanation)!=''">

        <tr><td class="{$firstColStyle}">

            Time explanation:</td><td class="{$secondColStyle}"><xsl:value-of select="timeScaleAgeExplanation"/></td></tr>

        </xsl:if>

        <xsl:if test="timeScaleCitation and normalize-space(timeScaleCitation)!=''">

        <tr><td class="{$firstColStyle}">

            Citation:</td><td class="{$secondColStyle}">

            <xsl:apply-templates select="timeScaleCitation"/>

        </td></tr>

        </xsl:if>

  </xsl:template>

  <xsl:template match="timeScaleCitation">

     <!-- Using citation module here -->

     <xsl:call-template name="citation">

     </xsl:call-template>

  </xsl:template>

<!-- ********************************************************************* -->

<!-- ***************  T A X O N O M I C   C O V E R A G E  *************** -->

<!-- ********************************************************************* -->

  <xsl:template name="taxonomicCoverage">

     <xsl:choose>

      <xsl:when test="references!=''">

        <xsl:variable name="ref_id" select="references"/>

        <xsl:variable name="references" select="$ids[@id=$ref_id]" />

        <xsl:for-each select="$references">

          <table class="{$tabledefaultStyle}">

            <xsl:call-template name="taxonomicCovCommon" />

          </table>

        </xsl:for-each>

      </xsl:when>

      <xsl:otherwise>

        <table class="{$tabledefaultStyle}">

          <xsl:call-template name="taxonomicCovCommon" />

        </table>

      </xsl:otherwise>

    </xsl:choose>

  </xsl:template>

  <xsl:template name="taxonomicCovCommon">

      <tr><th colspan="2">

      <xsl:text>Taxonomic Range:</xsl:text></th></tr>

      <xsl:apply-templates select="taxonomicSystem"/>

      <xsl:apply-templates select="generalTaxonomicCoverage"/>

      <xsl:for-each select="taxonomicClassification">

          <xsl:apply-templates select="."/>

      </xsl:for-each>

  </xsl:template>

 <xsl:template match="taxonomicSystem">

     <tr><td class="{$firstColStyle}">

        <xsl:text>Taxonomic System:</xsl:text></td>

        <td>

            <table class="{$tabledefaultStyle}">

              <xsl:apply-templates select="./*"/>

            </table>

        </td>

     </tr>

  </xsl:template>

  <xsl:template match="classificationSystem">

     <xsl:for-each select="classificationSystemCitation">

        <tr><td class="{$firstColStyle}">Classification Citation:</td>

          <td>

           <xsl:call-template name="citation">

             <xsl:with-param name="citationfirstColStyle" select="$firstColStyle"/>

             <xsl:with-param name="citationsubHeaderStyle" select="$subHeaderStyle"/>

           </xsl:call-template>

         </td>

        </tr>

     </xsl:for-each>

     <xsl:if test="classificationSystemModifications and normalize-space(classificationSystemModifications)!=''">

      <tr><td class="{$firstColStyle}">Modification:</td>

        <td class="{$secondColStyle}">

          <xsl:value-of select="classificationSystemModifications"/>

        </td>

      </tr>

     </xsl:if>

  </xsl:template>

  <xsl:template match="identificationReference">

      <tr><td class="{$firstColStyle}">ID Reference:</td>

          <td>

             <xsl:call-template name="citation">

                <xsl:with-param name="citationfirstColStyle" select="$firstColStyle"/>

                <xsl:with-param name="citationsubHeaderStyle" select="$subHeaderStyle"/>

             </xsl:call-template>

          </td>

     </tr>

  </xsl:template>

  <xsl:template match="identifierName">

      <tr><td class="{$firstColStyle}">ID Name:</td>

          <td>

             <xsl:call-template name="party">

               <xsl:with-param name="partyfirstColStyle" select="$firstColStyle"/>

             </xsl:call-template>

          </td>

      </tr>

  </xsl:template>

  <xsl:template match="taxonomicProcedures">

    <tr><td class="{$firstColStyle}">

        <xsl:text>Procedures:</xsl:text></td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

  </xsl:template>

  <xsl:template match="taxonomicCompleteness">

    <tr><td class="{$firstColStyle}">

        <xsl:text>Completeness:</xsl:text></td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

  </xsl:template>

  <xsl:template match="vouchers">

      <tr><td class="{$firstColStyle}">Vouchers:</td>

        <td>

        <table class="{$tabledefaultStyle}">

        <xsl:apply-templates select="specimen"/>

        <xsl:apply-templates select="repository"/>

        </table>

        </td></tr>

  </xsl:template>

  <xsl:template match="specimen">

    <tr><td class="{$firstColStyle}">

        <xsl:text>Specimen:</xsl:text></td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

  </xsl:template>

  <xsl:template match="repository">

    <tr><td class="{$firstColStyle}">Repository:</td>

        <td>

            <xsl:for-each select="originator">

               <xsl:call-template name="party">

                 <xsl:with-param name="partyfirstColStyle" select="$firstColStyle"/>

               </xsl:call-template>

            </xsl:for-each>

        </td>

    </tr>

  </xsl:template>

  <xsl:template match="generalTaxonomicCoverage">

      <tr><td class="{$firstColStyle}">

             <xsl:text>General Coverage:</xsl:text></td>

           <td class="{$secondColStyle}">

             <xsl:value-of select="."/>

          </td>

      </tr>

  </xsl:template>

  <xsl:template match="taxonomicClassification">

    <tr><td class="{$firstColStyle}">

        <xsl:text>Classification:</xsl:text></td><td>

        <table class="{$tabledefaultStyle}">

        <xsl:apply-templates select="./*" mode="nest"/>

        </table>

        </td></tr>

  </xsl:template>

  <xsl:template match="taxonRankName" mode="nest" >

      <tr><td class="{$firstColStyle}">

        <xsl:text>Rank Name:</xsl:text></td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

  </xsl:template>

  <xsl:template match="taxonRankValue" mode="nest">

      <tr><td class="{$firstColStyle}">

        <xsl:text>Rank Value:</xsl:text></td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

  </xsl:template>

  <xsl:template match="commonName" mode="nest">

      <tr><td class="{$firstColStyle}">

            <xsl:text>Common Name:</xsl:text></td><td class="{$secondColStyle}">

            <xsl:value-of select="."/>

          </td>

      </tr>

  </xsl:template>

  <xsl:template match="taxonomicClassification" mode="nest">

    <tr><td class="{$firstColStyle}">

          <xsl:text>Classification:</xsl:text>

        </td>

        <td>

           <table class="{$tabledefaultStyle}">

             <xsl:apply-templates select="./*" mode="nest"/>

           </table>

        </td>

     </tr>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author: cjones $'

  *     '$Date: 2006-11-17 13:37:07 -0800 (Fri, 17 Nov 2006) $'

  * '$Revision: 3094 $'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-variable.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="html" encoding="iso-8859-1"

              doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"

              doctype-system="http://www.w3.org/TR/html4/loose.dtd"

              indent="yes" />  

  <!-- This module is for party member and it is self contained-->

  <xsl:template name="party">

      <xsl:param name="partyfirstColStyle"/>

      <table class="{$tabledefaultStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:apply-templates mode="party">

             <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

            </xsl:apply-templates>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <xsl:apply-templates mode="party">

            <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

          </xsl:apply-templates>

        </xsl:otherwise>

      </xsl:choose>

      </table>

  </xsl:template>

  <!-- *********************************************************************** -->

  <xsl:template match="individualName" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

        <tr><td class="{$partyfirstColStyle}" >

            Individual:</td><td class="{$secondColStyle}" >

           <b><xsl:value-of select="./salutation"/><xsl:text> </xsl:text>

           <xsl:value-of select="./givenName"/><xsl:text> </xsl:text>

           <xsl:value-of select="./surName"/></b>

        </td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="organizationName" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

        <tr><td class="{$partyfirstColStyle}" >

        Organization:</td><td class="{$secondColStyle}">

        <b><xsl:value-of select="."/></b>

        </td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="positionName" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

      <tr><td class="{$partyfirstColStyle}">

        Position:</td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="address" mode="party">

    <xsl:param name="partyfirstColStyle"/>

    <xsl:if test="normalize-space(.)!=''">

      <xsl:call-template name="addressCommon">

         <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

      </xsl:call-template>

    </xsl:if>

    </xsl:template>

   <!-- This template will be call by other place-->

   <xsl:template name="address">

      <xsl:param name="partyfirstColStyle"/>

      <table class="{$tablepartyStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:call-template name="addressCommon">

             <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

            </xsl:call-template>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <xsl:call-template name="addressCommon">

             <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

          </xsl:call-template>

        </xsl:otherwise>

      </xsl:choose>

      </table>

  </xsl:template>

   <xsl:template name="addressCommon">

    <xsl:param name="partyfirstColStyle"/>

    <xsl:if test="normalize-space(.)!=''">

    <tr><td class="{$partyfirstColStyle}">

        Address:</td><td>

    <table class="{$tablepartyStyle}">

    <xsl:for-each select="deliveryPoint">

    <tr><td class="{$secondColStyle}"><xsl:value-of select="."/><xsl:text>, </xsl:text></td></tr>

    </xsl:for-each>

    <!-- only include comma if city exists... -->

    <tr><td class="{$secondColStyle}" >

    <xsl:if test="normalize-space(city)!=''">

        <xsl:value-of select="city"/><xsl:text>, </xsl:text>

    </xsl:if>

    <xsl:if test="normalize-space(administrativeArea)!='' or normalize-space(postalCode)!=''">

        <xsl:value-of select="administrativeArea"/><xsl:text> </xsl:text><xsl:value-of select="postalCode"/><xsl:text> </xsl:text>

    </xsl:if>

    <xsl:if test="normalize-space(country)!=''">

      <xsl:value-of select="country"/>

    </xsl:if></td></tr>

    </table></td></tr>

    </xsl:if>

   </xsl:template>

  <xsl:template match="phone" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <tr><td class="{$partyfirstColStyle}" >

             Phone:

          </td>

          <td>

            <table class="{$tablepartyStyle}">

              <tr><td class="{$secondColStyle}">

                     <xsl:value-of select="."/>

                     <xsl:if test="normalize-space(./@phonetype)!=''">

                       <xsl:text> (</xsl:text><xsl:value-of select="./@phonetype"/><xsl:text>)</xsl:text>

                     </xsl:if>

                   </td>

               </tr>

             </table>

          </td>

      </tr>

  </xsl:template>

  <xsl:template match="electronicMailAddress" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

       <tr><td class="{$partyfirstColStyle}" >

            Email Address:

          </td>

          <td>

            <table class="{$tablepartyStyle}">

              <tr><td class="{$secondColStyle}">

                    <a><xsl:attribute name="href">mailto:<xsl:value-of select="."/></xsl:attribute><xsl:value-of select="./entityName"/>

                    <xsl:value-of select="."/></a>

                   </td>

              </tr>

            </table>

          </td>

        </tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="onlineUrl" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

      <tr><td class="{$partyfirstColStyle}" >

            Web Address:

          </td>

          <td>

             <table class="{$tablepartyStyle}">

               <tr><td class="{$secondColStyle}">

                     <a><xsl:attribute name="href">http://<xsl:value-of select="."/></xsl:attribute><xsl:value-of select="./entityName"/>

                     <xsl:value-of select="."/></a>

                    </td>

               </tr>

             </table>

           </td>

        </tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="userId" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

      <tr><td class="{$partyfirstColStyle}" >

        Id:</td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="text()" mode="party" />

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author: barteau $'

  *     '$Date: 2008-01-15 17:12:44 -0800 (Tue, 15 Jan 2008) $'

  * '$Revision: 3689 $'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  *****************************************************************************

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet that provides a

  * single, central location for setting all installation-specific paths for

  * XSLT stylesheets.  It is intended to be imported (using the

  * <xsl:import href="..." /> element) into other XSLT stylesheets used in the

  * transformation of xml files that are valid with respect to the

  * applicable dtd of the Ecological Metadata Language (EML).

  * Some of these paths incorporate values of the form: @token-name@; these are

  * intended to allow an Ant (http://jakarta.apache.org/ant/index.html) build

  * script to replace the tokens automatically with the correct values at build/

  * install time.  If Ant is not used, the tokens may simply be edited by hand

  * to point to the correct resources.

  * Note that the values given below may be overridden by passing parameters to

  * the XSLT processor programatically, although the procedure for doing so is

  * vendor-specific.  Note also that these parameter definitions will be overridden

  * by any identical parameter names declared within xsl stylesheets that import

  * this stylesheet.

  *

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<!--

    /**

    *   The filename of the default css stylesheet to be used

    *   (filename only - not the whole path, and no ".css" extension.  The

    *   example below would look for a file named "default.css" in the same

    *   directory as the stylesheets

    */

-->

  <xsl:param name="qformat">default</xsl:param>

<!--

    /**

    *   The module which need to be display in eml2 document. The default

    *   value is dataset

    */

-->

  <xsl:param name="displaymodule">dataset</xsl:param>

<!--

    /**

    *   To show the links for the Entities in the dataset display module.

    */

-->

  <xsl:param name="withEntityLinks">1</xsl:param>

<!--

    /**

    *   To show the link for Additional Metadata in the dataset display module.

    */

-->

  <xsl:param name="withAdditionalMetadataLink">1</xsl:param>

<!--

    /**

    *   To show the link for the Original XML in the dataset display module.

    */

-->

  <xsl:param name="withOriginalXMLLink">1</xsl:param>

<!--

    /**

    *   To show any html links (emails and webpage).

    */

-->

  <xsl:param name="withHTMLLinks">1</xsl:param>

<!--

    /**

    *   To show the Attributes table in the entity display.

    */

-->

  <xsl:param name="withAttributes">1</xsl:param>

<!--

    /**

    *   To insert templates where header and footer are defined.

    */

-->

  <xsl:param name="insertTemplate">1</xsl:param>

<!--

   /**

    *   the path of the directory where the XSL and CSS files reside - starts

    *   with context name, eg: /myContextRoot/styleDirectory.

    *   (As found in "http://hostname:port/myContextRoot/styleDirectory").

    *   Needs leading slash but not trailing slash

    *

    *   EXAMPLE:

    *       <xsl:param name="stylePath">/brooke/style</xsl:param>

    */

-->

    <xsl:param name="stylePath">{$contextURL}/style/skins</xsl:param>

<!--

   /*

    *   the path of the directory where the common javascript and css files

    *   reside - i.e the files that are not skin-specific. Starts

    *   with context name, eg: /myContextRoot/styleCommonDirectory.

    *   (As found in "http://hostname:port/myContextRoot/styleCommonDirectory").

    *

    *   EXAMPLE

    *       <xsl:param name="styleCommonPath">/brooke/style/common</xsl:param>

    */

-->

    <xsl:param name="styleCommonPath">{$contextURL}/style/common</xsl:param>

<!--the docid of xml which is processed-->

    <xsl:param name="docid"/>

<!-- type of entity, data table or spacial raster or others-->

    <xsl:param name="entitytype"></xsl:param>

<!-- the index of entity in same entity type -->

    <xsl:param name="entityindex"/>

<!-- the index of attribute in same entity -->

    <xsl:param name="attributeindex"/>

<!-- the index of physical part in entity part-->

    <xsl:param name="physicalindex"/>

<!-- the index of distribution in physical part  -->

    <xsl:param name="distributionindex"/>

<!-- the levle of distribution -->

    <xsl:param name="distributionlevel"/>

<!-- the index of additional metadata-->

    <xsl:param name="additionalmetadataindex">1</xsl:param>

<!-- attribute set to get rid of cell spacing-->

    <xsl:attribute-set name="cellspacing">

      <xsl:attribute name="cellpadding">0</xsl:attribute>

      <xsl:attribute name="cellspacing">0</xsl:attribute>

    </xsl:attribute-set>

<!-- determines whether to use metacat or LSID identiers-->

	<xsl:param name="lsidauthority"></xsl:param>

<!-- the url for the data registry of the dataset-->

	<xsl:param name="registryurl"></xsl:param>

<!-- the name of the data registry of the dataset-->

	<xsl:param name="registryname"></xsl:param>

<!-- for getting the server context and cgi locations -->  

  <xsl:param name="contextURL"/>

  <xsl:param name="cgi-prefix"/>

<!-- for access to "protected" documents/files -->  

  <xsl:param name="sessionid"/>

<!--

    /**

    *   The base URI to be used for the href link to each document in a

    *   "subject-relationaship-object" triple

    *

    *   EXAMPLE:

    *       <xsl:param name="tripleURI">

    *         <![CDATA[/brooke/servlet/metacat?action=read&qformat=knb&docid=]]>

    *       </xsl:param>

    *

    *   (Note in the above case the "qformat=knb" parameter in the url; a system

    *   could pass this parameter to the XSLT engine to override the local

    *   <xsl:param name="qformat"> tags defined earlier in this document.)

    */

-->

  <xsl:param name="tripleURI"><xsl:value-of select="$contextURL" /><![CDATA[/metacat?action=read&qformat=]]><xsl:value-of select="$qformat" /><![CDATA[&sessionid=]]><xsl:value-of select="$sessionid" /><![CDATA[&docid=]]></xsl:param>

    <!-- URL for xmlformat-->

    <xsl:param name="xmlURI"><xsl:value-of select="$contextURL" /><![CDATA[/metacat?action=read&qformat=xml&docid=]]></xsl:param>

<!--

    /**

    *   Most of the html pages are currently laid out as a 2-column table, with

    *   highlights for more-major rows containing subsection titles etc.

    *   The following parameters are used within the

    *           <td width="whateverWidth" class="whateverClass">

    *   tags to define the column widths and (css) styles.

    *

    *   The values of the "xxxColWidth" parameters can be percentages (need to

    *   include % sign) or pixels (number only). Note that if a width is defined

    *   in the CSS stylesheet (see next paragraph), it will override this local

    *   width setting in browsers newer than NN4

    *

    *   The values of the "xxxColStyle" parameters refer to style definitions

    *   listed in the *.css stylesheet that is defined in this xsl document,

    *   above (in the <xsl:param name="qformat"> tag).

    *

    *   (Note that if the "qformat" is changed from the default by passing a

    *   value in the url (see notes for <xsl:param name="qformat"> tag, above),

    *   then the params below must match style names in the "new" CSS stylesheet

    */

-->

<!--    the style for major rows containing subsection titles etc. -->

  <xsl:param name="subHeaderStyle" select="'tablehead'"/>

<!--    the style for major rows containing links, such as additional metadata,

        original xml file etc. -->

  <xsl:param name="linkedHeaderStyle" select="'linkedHeaderStyle'"/>

<!--    the width for the first column (but see note above) -->

  <xsl:param name="firstColWidth" select="'15%'"/>

<!-- the style for the first column -->

  <xsl:param name="firstColStyle" select="'rowodd'"/>

<!--    the width for the second column (but see note above) -->

  <xsl:param name="secondColWidth" select="'85%'"/>

<!-- the style for the second column -->

  <xsl:param name="secondColStyle" select="'roweven'"/>

<!-- the style for the attribute table -->

  <xsl:param name="tableattributeStyle" select="'tableattribute'"/>

<!-- the style for the border -->

  <xsl:param name="borderStyle" select="'bordered'"/>

<!-- the style for the even col in attributes table -->

  <xsl:param name="colevenStyle" select="'coleven'"/>

<!-- the style for the inner even col in attributes table -->

  <xsl:param name="innercolevenStyle" select="'innercoleven'"/>

<!-- the style for the odd col in attributes table -->

  <xsl:param name="coloddStyle" select="'colodd'"/>

<!-- the style for the inner odd col in attributes table -->

  <xsl:param name="innercoloddStyle" select="'innercolodd'"/>

<!-- the default alignment style for the wrapper around the main tables -->

  <!--

  <xsl:param name="mainTableAligmentStyle" select="'mainTableAligmentStyle'"/>

  -->

  <xsl:param name="mainTableAligmentStyle" select="'content'"/>

<!-- the default style for the main container table -->

  <xsl:param name="mainContainerTableStyle" select="'group group_border'"/>

<!-- the default style for all other tables -->

  <xsl:param name="tabledefaultStyle" select="'subGroup subGroup_border onehundred_percent'"/>

<!-- the style for table party -->

  <xsl:param name="tablepartyStyle" select="'tableparty'"/>

<!-- Some html pages use a nested table in the second column.

     Some of these nested tables set their first column to

     the following width: -->

  <xsl:param name="secondColIndent" select="'10%'"/>

<!-- the first column width of attribute table-->

  <xsl:param name="attributefirstColWidth" select="'15%'"/>

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author: cjones $'

  *     '$Date: 2006-11-17 13:37:07 -0800 (Fri, 17 Nov 2006) $'

  * '$Revision: 3094 $'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-variable.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="html" encoding="iso-8859-1"

              doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"

              doctype-system="http://www.w3.org/TR/html4/loose.dtd"

              indent="yes" />  

  <xsl:template name="protocol">

    <xsl:param name="protocolfirstColStyle"/>

    <xsl:param name="protocolsubHeaderStyle"/>

    <table class="{$tabledefaultStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:call-template name="protocolcommon">

              <xsl:with-param name="protocolfirstColStyle" select="$protocolfirstColStyle"/>

              <xsl:with-param name="protocolsubHeaderStyle" select="$protocolsubHeaderStyle"/>

            </xsl:call-template>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

           <xsl:call-template name="protocolcommon">

              <xsl:with-param name="protocolfirstColStyle" select="$protocolfirstColStyle"/>

              <xsl:with-param name="protocolsubHeaderStyle" select="$protocolsubHeaderStyle"/>

           </xsl:call-template>

        </xsl:otherwise>

      </xsl:choose>

    </table>

  </xsl:template>

   <xsl:template name="protocolcommon">

        <xsl:param name="protocolfirstColStyle"/>

        <xsl:param name="protocolsubHeaderStyle"/>

        <xsl:call-template name="resource">

           <xsl:with-param name="resfirstColStyle" select="$protocolfirstColStyle"/>

           <xsl:with-param name="ressubHeaderStyle" select="$protocolsubHeaderStyle"/>

           <xsl:with-param name="creator">Author(s):</xsl:with-param>

        </xsl:call-template>

        <xsl:for-each select="proceduralStep">

          <tr><td colspan="2" class="{$protocolsubHeaderStyle}">

              Step<xsl:text> </xsl:text><xsl:value-of select="position()"/>:

              </td>

          </tr>

          <xsl:call-template name="step">

              <xsl:with-param name="protocolfirstColStyle" select="$protocolfirstColStyle"/>

              <xsl:with-param name="protocolsubHeaderStyle" select="$protocolsubHeaderStyle"/>

          </xsl:call-template>

        </xsl:for-each>

        <xsl:call-template name="protocolAccess">

              <xsl:with-param name="protocolfirstColStyle" select="$protocolfirstColStyle"/>

              <xsl:with-param name="protocolsubHeaderStyle" select="$protocolsubHeaderStyle"/>

        </xsl:call-template>

  </xsl:template>

  <xsl:template name="step">

    <xsl:param name="protocolfirstColStyle"/>

    <xsl:param name="protocolsubHeaderStyle"/>

    <xsl:for-each select="description">

      <tr><td class="{$protocolfirstColStyle}">

          Description:

          </td>

          <td>

             <xsl:call-template name="text">

               <xsl:with-param name="textfirstColStyle" select="$protocolfirstColStyle"/>

             </xsl:call-template>

          </td>

      </tr>

     </xsl:for-each>

    <xsl:for-each select="citation">

      <tr><td class="{$protocolfirstColStyle}">

          Citation:

          </td>

          <td class="{$secondColStyle}">

            

          </td>

      </tr>

      <tr><td colspan="2">

          <xsl:call-template name="citation">

            <xsl:with-param name="citationfirstColStyle" select="$protocolfirstColStyle"/>

            <xsl:with-param name="citationsubHeaderStyle" select="$protocolsubHeaderStyle"/>

          </xsl:call-template>

          </td>

      </tr>

    </xsl:for-each>

     <xsl:for-each select="protocol">

      <tr><td class="{$protocolfirstColStyle}">

          Protocol:

          </td>

          <td class="{$secondColStyle}">

            

          </td>

      </tr>

      <tr><td colspan="2">

          <xsl:call-template name="protocol">

            <xsl:with-param name="protocolfirstColStyle" select="$protocolfirstColStyle"/>

            <xsl:with-param name="protocolsubHeaderStyle" select="$protocolsubHeaderStyle"/>

          </xsl:call-template>

          </td>

      </tr>

    </xsl:for-each>

    <xsl:for-each select="instrumentation">

        <tr><td class="{$protocolfirstColStyle}">

          Instrument(s):

          </td>

          <td class="{$secondColStyle}">

            <xsl:value-of select="."/>

          </td>

      </tr>

    </xsl:for-each>

    <xsl:for-each select="software">

     <tr><td colspan="2">

          <xsl:call-template name="software">

            <xsl:with-param name="softwarefirstColStyle" select="$protocolfirstColStyle"/>

            <xsl:with-param name="softwaresubHeaderStyle" select="$protocolsubHeaderStyle"/>

          </xsl:call-template>

          </td>

      </tr>

    </xsl:for-each>

    <xsl:for-each select="subStep">

      <tr><td class="{$protocolfirstColStyle}">

          Substep<xsl:text> </xsl:text><xsl:value-of select="position()"/>

          </td>

          <td class="{$secondColStyle}">

            

          </td>

      </tr>

      <xsl:call-template name="step">

          <xsl:with-param name="protocolfirstColStyle" select="$protocolfirstColStyle"/>

          <xsl:with-param name="protocolsubHeaderStyle" select="$protocolsubHeaderStyle"/>

      </xsl:call-template>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="protocolAccess">

    <xsl:param name="protocolfirstColStyle"/>

    <xsl:param name="protocolsubHeaderStyle"/>

    <xsl:for-each select="access">

      <tr><td colspan="2">

         <xsl:call-template name="access">

           <xsl:with-param name="accessfirstColStyle" select="$protocolfirstColStyle"/>

           <xsl:with-param name="accesssubHeaderStyle" select="$protocolsubHeaderStyle"/>

         </xsl:call-template>

         </td>

       </tr>

    </xsl:for-each>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matt Jones

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author: cjones $'

  *     '$Date: 2006-11-17 13:37:07 -0800 (Fri, 17 Nov 2006) $'

  * '$Revision: 3094 $'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-dataset.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="html" encoding="iso-8859-1"

    doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN"

    doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"

    indent="yes" />  

  <xsl:template name="access">

    <xsl:param name="accessfirstColStyle"/>

    <xsl:param name="accesssubHeaderStyle"/>

    <table class="{$tabledefaultStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:call-template name="accessCommon">

             <xsl:with-param name="accessfirstColStyle" select="$accessfirstColStyle"/>

             <xsl:with-param name="accesssubHeaderStyle" select="$accesssubHeaderStyle"/>

            </xsl:call-template>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <xsl:call-template name="accessCommon">

             <xsl:with-param name="accessfirstColStyle" select="$accessfirstColStyle"/>

             <xsl:with-param name="accesssubHeaderStyle" select="$accesssubHeaderStyle"/>

          </xsl:call-template>

        </xsl:otherwise>

      </xsl:choose>

    </table>

  </xsl:template>

  <xsl:template name="accessCommon">

     <xsl:param name="accessfirstColStyle" />

     <xsl:param name="accesssubHeaderStyle"/>

        <xsl:call-template name="accesssystem">

           <xsl:with-param name="accessfirstColStyle" select="$accessfirstColStyle"/>

           <xsl:with-param name="accesssubHeaderStyle" select="$accesssubHeaderStyle"/>

        </xsl:call-template>

        <xsl:if test="normalize-space(./@order)='allowFirst' and (allow)">

            <xsl:call-template name="allow_deny">

                <xsl:with-param name="permission" select="'allow'"/>

                <xsl:with-param name="accessfirstColStyle" select="$accessfirstColStyle"/>

             </xsl:call-template>

        </xsl:if>

        <xsl:if test="(deny)">

           <xsl:call-template name="allow_deny">

                <xsl:with-param name="permission" select="'deny'"/>

                <xsl:with-param name="accessfirstColStyle" select="$accessfirstColStyle"/>

            </xsl:call-template>

        </xsl:if>

        <xsl:if test="normalize-space(acl/@order)='denyFirst' and (allow)">

            <xsl:call-template name="allow_deny">

                <xsl:with-param name="permission" select="'allow'"/>

                <xsl:with-param name="accessfirstColStyle" select="$accessfirstColStyle"/>

            </xsl:call-template>

        </xsl:if>

  </xsl:template>

  <xsl:template name="allow_deny">

   <xsl:param name="permission"/>

   <xsl:param name="accessfirstColStyle" />

   <xsl:choose>

       <xsl:when test="$permission='allow'">

          <xsl:for-each select="allow">

            <tr>

              <td class="{$accessfirstColStyle}">

               Allow:

              </td>

              <td class="{$accessfirstColStyle}">

                <xsl:for-each select="./permission">

                  <xsl:text>[</xsl:text><xsl:value-of select="."/><xsl:text>] </xsl:text>

                </xsl:for-each>

              </td>

              <td class="{$accessfirstColStyle}" >

                <xsl:for-each select="principal">

                  <xsl:value-of select="."/><br/>

                </xsl:for-each>

              </td>

            </tr>

          </xsl:for-each>

       </xsl:when>

       <xsl:otherwise>

         <xsl:for-each select="deny">

            <tr>

              <td class="{$accessfirstColStyle}">

               Deny:

              </td>

              <td class="{$accessfirstColStyle}">

                <xsl:for-each select="./permission">

                  <xsl:text>[</xsl:text><xsl:value-of select="."/><xsl:text>] </xsl:text>

                </xsl:for-each>

              </td>

              <td class="{$accessfirstColStyle}" >

                <xsl:for-each select="principal">

                  <xsl:value-of select="."/><br/>

                </xsl:for-each>

              </td>

            </tr>

         </xsl:for-each>

       </xsl:otherwise>

   </xsl:choose>

   </xsl:template>

  <xsl:template name="accesssystem">

       <xsl:param name="accessfirstColStyle" />

        <tr>

          <th colspan="3">

            <xsl:text>Access Control:</xsl:text>

          </th>

        </tr>

        <tr>

          <td class="{$accessfirstColStyle}">Auth System:</td>

          <td class="{$secondColStyle}"><xsl:value-of select="./@authSystem"/></td>

        </tr>

        <tr>

          <td class="{$accessfirstColStyle}">Order:</td>

          <td class="{$secondColStyle}"><xsl:value-of select="./@order"/></td>

        </tr>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile: eml.xsl,v $'

  *      Authors: Matt Jones

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author: obrien $'

  *     '$Date: 2008-08-28 22:59:33 $'

  * '$Revision: 1.8 $'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-dataset.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->