Metacat

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author$'

  *     '$Date$'

  * '$Revision$'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-variable.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="html" encoding="iso-8859-1"

              doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"

              doctype-system="http://www.w3.org/TR/html4/loose.dtd"

              indent="yes" />  

  <!-- This module is for party member and it is self contained-->

  <xsl:template name="party">

      <xsl:param name="partyfirstColStyle"/>

      <table class="{$tabledefaultStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:apply-templates mode="party">

             <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

            </xsl:apply-templates>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <xsl:apply-templates mode="party">

            <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

          </xsl:apply-templates>

        </xsl:otherwise>

      </xsl:choose>

      </table>

  </xsl:template>

  <!-- *********************************************************************** -->

  <xsl:template match="individualName" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

        <tr><td class="{$partyfirstColStyle}" >

            Individual:</td><td class="{$secondColStyle}" >

           <b><xsl:value-of select="./salutation"/><xsl:text> </xsl:text>

           <xsl:value-of select="./givenName"/><xsl:text> </xsl:text>

           <xsl:value-of select="./surName"/></b>

        </td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="organizationName" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

        <tr><td class="{$partyfirstColStyle}" >

        Organization:</td><td class="{$secondColStyle}">

        <b><xsl:value-of select="."/></b>

        </td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="positionName" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

      <tr><td class="{$partyfirstColStyle}">

        Position:</td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="address" mode="party">

    <xsl:param name="partyfirstColStyle"/>

    <xsl:if test="normalize-space(.)!=''">

      <xsl:call-template name="addressCommon">

         <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

      </xsl:call-template>

    </xsl:if>

    </xsl:template>

   <!-- This template will be call by other place-->

   <xsl:template name="address">

      <xsl:param name="partyfirstColStyle"/>

      <table class="{$tablepartyStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:call-template name="addressCommon">

             <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

            </xsl:call-template>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <xsl:call-template name="addressCommon">

             <xsl:with-param name="partyfirstColStyle" select="$partyfirstColStyle"/>

          </xsl:call-template>

        </xsl:otherwise>

      </xsl:choose>

      </table>

  </xsl:template>

   <xsl:template name="addressCommon">

    <xsl:param name="partyfirstColStyle"/>

    <xsl:if test="normalize-space(.)!=''">

    <tr><td class="{$partyfirstColStyle}">

        Address:</td><td>

    <table class="{$tablepartyStyle}">

    <xsl:for-each select="deliveryPoint">

    <tr><td class="{$secondColStyle}"><xsl:value-of select="."/><xsl:text>, </xsl:text></td></tr>

    </xsl:for-each>

    <!-- only include comma if city exists... -->

    <tr><td class="{$secondColStyle}" >

    <xsl:if test="normalize-space(city)!=''">

        <xsl:value-of select="city"/><xsl:text>, </xsl:text>

    </xsl:if>

    <xsl:if test="normalize-space(administrativeArea)!='' or normalize-space(postalCode)!=''">

        <xsl:value-of select="administrativeArea"/><xsl:text> </xsl:text><xsl:value-of select="postalCode"/><xsl:text> </xsl:text>

    </xsl:if>

    <xsl:if test="normalize-space(country)!=''">

      <xsl:value-of select="country"/>

    </xsl:if></td></tr>

    </table></td></tr>

    </xsl:if>

   </xsl:template>

  <xsl:template match="phone" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <tr><td class="{$partyfirstColStyle}" >

             Phone:

          </td>

          <td>

            <table class="{$tablepartyStyle}">

              <tr><td class="{$secondColStyle}">

                     <xsl:value-of select="."/>

                     <xsl:if test="normalize-space(./@phonetype)!=''">

                       <xsl:text> (</xsl:text><xsl:value-of select="./@phonetype"/><xsl:text>)</xsl:text>

                     </xsl:if>

                   </td>

               </tr>

             </table>

          </td>

      </tr>

  </xsl:template>

  <xsl:template match="electronicMailAddress" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

       <tr><td class="{$partyfirstColStyle}" >

            Email Address:

          </td>

          <td>

            <table class="{$tablepartyStyle}">

              <tr><td class="{$secondColStyle}">

                    <a><xsl:attribute name="href">mailto:<xsl:value-of select="."/></xsl:attribute>

                    <xsl:value-of select="."/></a>

                   </td>

              </tr>

            </table>

          </td>

        </tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="onlineUrl" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

      <tr><td class="{$partyfirstColStyle}" >

            Web Address:

          </td>

          <td>

             <table class="{$tablepartyStyle}">

               <tr><td class="{$secondColStyle}">

                     <a><xsl:attribute name="href"><xsl:value-of select="."/></xsl:attribute>

                     <xsl:value-of select="."/></a>

                    </td>

               </tr>

             </table>

           </td>

        </tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="userId" mode="party">

      <xsl:param name="partyfirstColStyle"/>

      <xsl:if test="normalize-space(.)!=''">

      <tr><td class="{$partyfirstColStyle}" >

        Id:</td><td class="{$secondColStyle}">

        <xsl:value-of select="."/></td></tr>

      </xsl:if>

  </xsl:template>

  <xsl:template match="text()" mode="party" />

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author$'

  *     '$Date$'

  * '$Revision$'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  *****************************************************************************

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet that provides a

  * single, central location for setting all installation-specific paths for

  * XSLT stylesheets.  It is intended to be imported (using the

  * <xsl:import href="..." /> element) into other XSLT stylesheets used in the

  * transformation of xml files that are valid with respect to the

  * applicable dtd of the Ecological Metadata Language (EML).

  * Some of these paths incorporate values of the form: @token-name@; these are

  * intended to allow an Ant (http://jakarta.apache.org/ant/index.html) build

  * script to replace the tokens automatically with the correct values at build/

  * install time.  If Ant is not used, the tokens may simply be edited by hand

  * to point to the correct resources.

  * Note that the values given below may be overridden by passing parameters to

  * the XSLT processor programatically, although the procedure for doing so is

  * vendor-specific.  Note also that these parameter definitions will be overridden

  * by any identical parameter names declared within xsl stylesheets that import

  * this stylesheet.

  *

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<!--

    /**

    *   The filename of the default css stylesheet to be used

    *   (filename only - not the whole path, and no ".css" extension.  The

    *   example below would look for a file named "default.css" in the same

    *   directory as the stylesheets

    */

-->

  <xsl:param name="qformat">default</xsl:param>

<!--

    /**

    *   The module which need to be display in eml2 document. The default

    *   value is dataset

    */

-->

  <xsl:param name="displaymodule">dataset</xsl:param>

<!--

    /**

    *   To show the links for the Entities in the dataset display module.

    */

-->

  <xsl:param name="withEntityLinks">1</xsl:param>

<!--

    /**

    *   To show the link for Additional Metadata in the dataset display module.

    */

-->

  <xsl:param name="withAdditionalMetadataLink">1</xsl:param>

<!--

    /**

    *   To show the link for the Original XML in the dataset display module.

    */

-->

  <xsl:param name="withOriginalXMLLink">1</xsl:param>

<!--

    /**

    *   To show any html links (emails and webpage).

    */

-->

  <xsl:param name="withHTMLLinks">1</xsl:param>

<!--

    /**

    *   To show the Attributes table in the entity display.

    */

-->

  <xsl:param name="withAttributes">1</xsl:param>

<!--

    /**

    *   To insert templates where header and footer are defined.

    */

-->

  <xsl:param name="insertTemplate">1</xsl:param>

<!--the docid of xml which is processed-->

    <xsl:param name="docid"/>

<!-- type of entity, data table or spacial raster or others-->

    <xsl:param name="entitytype"></xsl:param>

<!-- the index of entity in same entity type -->

    <xsl:param name="entityindex"/>

<!-- the index of attribute in same entity -->

    <xsl:param name="attributeindex"/>

<!-- the index of physical part in entity part-->

    <xsl:param name="physicalindex"/>

<!-- the index of distribution in physical part  -->

    <xsl:param name="distributionindex"/>

<!-- the levle of distribution -->

    <xsl:param name="distributionlevel"/>

<!-- the index of additional metadata-->

    <xsl:param name="additionalmetadataindex">1</xsl:param>

<!-- attribute set to get rid of cell spacing-->

    <xsl:attribute-set name="cellspacing">

      <xsl:attribute name="cellpadding">0</xsl:attribute>

      <xsl:attribute name="cellspacing">0</xsl:attribute>

    </xsl:attribute-set>

<!-- determines whether to use metacat or LSID identiers-->

	<xsl:param name="lsidauthority"></xsl:param>

<!-- the url for the data registry of the dataset-->

	<xsl:param name="registryurl"></xsl:param>

<!-- the name of the data registry of the dataset-->

	<xsl:param name="registryname"></xsl:param>

<!-- for getting the server context and cgi locations -->  

  <xsl:param name="contextURL"/>

  <xsl:param name="cgi-prefix"/>

<!-- for access to "protected" documents/files -->  

  <xsl:param name="sessionid"/>

<!--

    /**

    *   The base URI to be used for the href link to each document in a

    *   "subject-relationaship-object" triple

    *

    *   EXAMPLE:

    *       <xsl:param name="tripleURI">

    *         <![CDATA[/brooke/servlet/metacat?action=read&qformat=knb&docid=]]>

    *       </xsl:param>

    *

    *   (Note in the above case the "qformat=knb" parameter in the url; a system

    *   could pass this parameter to the XSLT engine to override the local

    *   <xsl:param name="qformat"> tags defined earlier in this document.)

    */

-->

  <xsl:param name="tripleURI"><xsl:value-of select="$contextURL" /><![CDATA[/metacat?action=read&qformat=]]><xsl:value-of select="$qformat" /><![CDATA[&sessionid=]]><xsl:value-of select="$sessionid" /><![CDATA[&docid=]]></xsl:param>

    <!-- URL for xmlformat-->

    <xsl:param name="xmlURI"><xsl:value-of select="$contextURL" /><![CDATA[/metacat?action=read&qformat=xml]]><![CDATA[&sessionid=]]><xsl:value-of select="$sessionid" /><![CDATA[&docid=]]></xsl:param>

<!--

    /**

    *   Most of the html pages are currently laid out as a 2-column table, with

    *   highlights for more-major rows containing subsection titles etc.

    *   The following parameters are used within the

    *           <td width="whateverWidth" class="whateverClass">

    *   tags to define the column widths and (css) styles.

    *

    *   The values of the "xxxColWidth" parameters can be percentages (need to

    *   include % sign) or pixels (number only). Note that if a width is defined

    *   in the CSS stylesheet (see next paragraph), it will override this local

    *   width setting in browsers newer than NN4

    *

    *   The values of the "xxxColStyle" parameters refer to style definitions

    *   listed in the *.css stylesheet that is defined in this xsl document,

    *   above (in the <xsl:param name="qformat"> tag).

    *

    *   (Note that if the "qformat" is changed from the default by passing a

    *   value in the url (see notes for <xsl:param name="qformat"> tag, above),

    *   then the params below must match style names in the "new" CSS stylesheet

    */

-->

<!--    the style for major rows containing subsection titles etc. -->

  <xsl:param name="subHeaderStyle" select="'tablehead'"/>

<!--    the style for major rows containing links, such as additional metadata,

        original xml file etc. -->

  <xsl:param name="linkedHeaderStyle" select="'linkedHeaderStyle'"/>

<!--    the width for the first column (but see note above) -->

  <xsl:param name="firstColWidth" select="'15%'"/>

<!-- the style for the first column -->

  <xsl:param name="firstColStyle" select="'rowodd'"/>

<!--    the width for the second column (but see note above) -->

  <xsl:param name="secondColWidth" select="'85%'"/>

<!-- the style for the second column -->

  <xsl:param name="secondColStyle" select="'roweven'"/>

<!-- the style for the attribute table -->

  <xsl:param name="tableattributeStyle" select="'tableattribute'"/>

<!-- the style for the border -->

  <xsl:param name="borderStyle" select="'bordered'"/>

<!-- the style for the even col in attributes table -->

  <xsl:param name="colevenStyle" select="'coleven'"/>

<!-- the style for the inner even col in attributes table -->

  <xsl:param name="innercolevenStyle" select="'innercoleven'"/>

<!-- the style for the odd col in attributes table -->

  <xsl:param name="coloddStyle" select="'colodd'"/>

<!-- the style for the inner odd col in attributes table -->

  <xsl:param name="innercoloddStyle" select="'innercolodd'"/>

<!-- the default alignment style for the wrapper around the main tables -->

  <!--

  <xsl:param name="mainTableAligmentStyle" select="'mainTableAligmentStyle'"/>

  -->

  <xsl:param name="mainTableAligmentStyle" select="'content'"/>

<!-- the default style for the main container table -->

  <xsl:param name="mainContainerTableStyle" select="'group group_border'"/>

<!-- the default style for all other tables -->

  <xsl:param name="tabledefaultStyle" select="'subGroup subGroup_border onehundred_percent'"/>

<!-- the style for table party -->

  <xsl:param name="tablepartyStyle" select="'tableparty'"/>

<!-- Some html pages use a nested table in the second column.

     Some of these nested tables set their first column to

     the following width: -->

  <xsl:param name="secondColIndent" select="'10%'"/>

<!-- the first column width of attribute table-->

  <xsl:param name="attributefirstColWidth" select="'15%'"/>

<!--

   /**

    *   the path of the directory where the XSL and CSS files reside - starts

    *   with context name, eg: /myContextRoot/styleDirectory.

    *   (As found in "http://hostname:port/myContextRoot/styleDirectory").

    *   Needs leading slash but not trailing slash

    *

    *   EXAMPLE:

    *       <xsl:param name="stylePath">/brooke/style</xsl:param>

    */

-->

    <xsl:param name="stylePath"><xsl:value-of select="$contextURL" />/style/skins</xsl:param>

<!--

   /*

    *   the path of the directory where the common javascript and css files

    *   reside - i.e the files that are not skin-specific. Starts

    *   with context name, eg: /myContextRoot/styleCommonDirectory.

    *   (As found in "http://hostname:port/myContextRoot/styleCommonDirectory").

    *

    *   EXAMPLE

    *       <xsl:param name="styleCommonPath">/brooke/style/common</xsl:param>

    */

-->

    <xsl:param name="styleCommonPath"><xsl:value-of select="$contextURL" />/style/common</xsl:param>

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author$'

  *     '$Date$'

  * '$Revision$'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-variable.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="html" encoding="iso-8859-1"

              doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"

              doctype-system="http://www.w3.org/TR/html4/loose.dtd"

              indent="yes" />  

   <xsl:template name="project">

      <xsl:param name="projectfirstColStyle"/>

      <table class="{$tabledefaultStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:call-template name="projectcommon">

             <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

            </xsl:call-template>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <xsl:call-template name="projectcommon">

             <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

           </xsl:call-template>

        </xsl:otherwise>

      </xsl:choose>

      </table>

  </xsl:template>

  <xsl:template name="projectcommon">

    <xsl:param name="projectfirstColStyle"/>

    <xsl:call-template name="projecttitle">

      <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="projectpersonnel">

      <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="projectabstract">

      <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="projectfunding">

      <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

    </xsl:call-template>

   <xsl:call-template name="projectstudyareadescription">

      <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="projectdesigndescription">

      <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="projectrelatedproject">

      <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

    </xsl:call-template>

  </xsl:template>

   <xsl:template name="projecttitle">

     <xsl:param name="projectfirstColStyle"/>

     <xsl:for-each select="title">

        <tr><td class="{$projectfirstColStyle}">

             Title:

             </td>

             <td class="{$secondColStyle}" >

              <xsl:value-of select="../title"/>

             </td>

       </tr>

     </xsl:for-each>

  </xsl:template>

  <xsl:template name="projectpersonnel">

     <xsl:param name="projectfirstColStyle"/>

     <tr><td class="{$projectfirstColStyle}">

          Personnel:

          </td>

          <td>

             <table>

                 <xsl:for-each select="personnel">

                       <tr><td colspan="2">

                              <xsl:call-template name="party">

                                 <xsl:with-param name="partyfirstColStyle" select="$projectfirstColStyle"/>

                              </xsl:call-template>

                       </td></tr>

                       <xsl:for-each select="role">

                          <tr><td class="{$projectfirstColStyle}">

                                 Role:

                               </td>

                               <td>

                                 <table class="{$tablepartyStyle}">

                                     <tr>

                                         <td class="{$secondColStyle}">

                                            <xsl:value-of select="."/>

                                          </td>

                                      </tr>

                                  </table>

                               </td>

                          </tr>

                      </xsl:for-each>

                </xsl:for-each>

             </table>

         </td>

     </tr>

  </xsl:template>

   <xsl:template name="projectabstract">

     <xsl:param name="projectfirstColStyle"/>

     <xsl:for-each select="abstract">

       <tr><td class="{$projectfirstColStyle}">

          Abstract:

          </td>

          <td>

             <xsl:call-template name="text">

                <xsl:with-param name="textfirstColStyle" select="$projectfirstColStyle"/>

             </xsl:call-template>

         </td>

       </tr>

     </xsl:for-each>

  </xsl:template>

  <xsl:template name="projectfunding">

     <xsl:param name="projectfirstColStyle"/>

     <xsl:for-each select="funding">

       <tr><td class="{$projectfirstColStyle}">

          Funding:

          </td>

          <td>

              <xsl:call-template name="text">

                 <xsl:with-param name="textfirstColStyle" select="$projectfirstColStyle"/>

              </xsl:call-template>

         </td>

       </tr>

    </xsl:for-each>

  </xsl:template>

   <xsl:template name="projectstudyareadescription">

     <xsl:param name="projectfirstColStyle"/>

     <xsl:for-each select="studyAreaDescription">

       <tr><td class="{$projectfirstColStyle}">

           <xsl:text>Study Area:</xsl:text>

          </td>

          <td>

              <table class="{$tabledefaultStyle}">

                  <xsl:for-each select="descriptor">

                      <xsl:for-each select="descriptorValue">

                      <tr><td class="{$projectfirstColStyle}">

                            <xsl:value-of select="../@name"/>

                          </td>

                          <td class="{$secondColStyle}">

                             <xsl:choose>

                                <xsl:when test="./@citableClassificationSystem">

                                  <xsl:value-of select="."/>&#160;<xsl:value-of select="./@name_or_id"/>

                                </xsl:when>

                                <xsl:otherwise>

                                  <xsl:value-of select="."/>&#160;<xsl:value-of select="./@name_or_id"/>&#160;(No Citable Classification System)

                                </xsl:otherwise>

                              </xsl:choose>

                          </td>

                      </tr>

                      </xsl:for-each>

                      <xsl:for-each select="citation">

                        <tr><td class="{$projectfirstColStyle}">

                              Citation:

                            </td>

                            <td>

                             <xsl:call-template name="citation">

                                  <xsl:with-param name="citationfirstColStyle" select="projectfirstColStyle"/>

                             </xsl:call-template>

                           </td>

                       </tr>

                    </xsl:for-each>

               </xsl:for-each>

            </table>

         </td>

       </tr>

       <xsl:for-each select="citation">

         <tr><td class="{$projectfirstColStyle}">

          Study Area Citation:

          </td>

          <td>

              <xsl:call-template name="citation">

                   <xsl:with-param name="citationfirstColStyle" select="projectfirstColStyle"/>

               </xsl:call-template>

          </td>

        </tr>

      </xsl:for-each>

       <xsl:for-each select="coverage">

        <tr><td class="{$projectfirstColStyle}">

          Study Area Coverage:

          </td>

          <td>

             <xsl:call-template name="coverage"/>

          </td>

        </tr>

      </xsl:for-each>

    </xsl:for-each>

   </xsl:template>

  <xsl:template name="projectdesigndescription">

    <xsl:param name="projectfirstColStyle"/>

    <xsl:for-each select="designDescription">

       <xsl:for-each select="description">

        <tr><td class="{$projectfirstColStyle}">

          Design Description:

          </td>

          <td>

             <xsl:call-template name="text"/>

         </td>

       </tr>

      </xsl:for-each>

      <xsl:for-each select="citation">

        <tr><td class="{$projectfirstColStyle}">

          Design Citation:

          </td>

          <td >

             <xsl:call-template name="citation"/>

         </td>

       </tr>

      </xsl:for-each>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="projectrelatedproject">

    <xsl:param name="projectfirstColStyle"/>

    <xsl:for-each select="relatedProject">

       <tr><td class="{$projectfirstColStyle}">

          Related Project:

          </td>

          <td>

            <xsl:call-template name="project">

              <xsl:with-param name="projectfirstColStyle" select="$projectfirstColStyle"/>

            </xsl:call-template>

         </td>

       </tr>

    </xsl:for-each>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Jivka Bojilova

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author$'

  *     '$Date$'

  * '$Revision$'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-file.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="html" encoding="iso-8859-1"

              doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"

              doctype-system="http://www.w3.org/TR/html4/loose.dtd"

              indent="yes" />  

  <!-- This module is for datatable module-->

  <xsl:template name="storedProcedure">

      <xsl:param name="storedprocedurefirstColStyle"/>

      <xsl:param name="storedproceduresubHeaderStyle"/>

      <xsl:param name="docid"/>

      <xsl:param name="entityindex"/>

      <table xsl:use-attribute-sets="cellspacing" class="{$tabledefaultStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:call-template name="storedProcedureCommon">

             <xsl:with-param name="storedprocedurefirstColStyle" select="$storedprocedurefirstColStyle"/>

             <xsl:with-param name="storedproceduresubHeaderStyle" select="$storedproceduresubHeaderStyle"/>

             <xsl:with-param name="docid" select="$docid"/>

             <xsl:with-param name="entityindex" select="$entityindex"/>

            </xsl:call-template>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

           <xsl:call-template name="storedProcedureCommon">

             <xsl:with-param name="storedprocedurefirstColStyle" select="$storedprocedurefirstColStyle"/>

             <xsl:with-param name="storedproceduresubHeaderStyle" select="$storedproceduresubHeaderStyle"/>

             <xsl:with-param name="docid" select="$docid"/>

             <xsl:with-param name="entityindex" select="$entityindex"/>

            </xsl:call-template>

         </xsl:otherwise>

      </xsl:choose>

      </table>

  </xsl:template>

  <xsl:template name="storedProcedureCommon">

    <xsl:param name="storedprocedurefirstColStyle"/>

    <xsl:param name="storedproceduresubHeaderStyle"/>

    <xsl:param name="docid"/>

    <xsl:param name="entityindex"/>

    <xsl:for-each select="entityName">

       <xsl:call-template name="entityName">

          <xsl:with-param name="entityfirstColStyle" select="$storedprocedurefirstColStyle"/>

       </xsl:call-template>

    </xsl:for-each>

    <xsl:for-each select="alternateIdentifier">

       <xsl:call-template name="entityalternateIdentifier">

          <xsl:with-param name="entityfirstColStyle" select="$storedprocedurefirstColStyle"/>

       </xsl:call-template>

    </xsl:for-each>

    <xsl:for-each select="entityDescription">

       <xsl:call-template name="entityDescription">

          <xsl:with-param name="entityfirstColStyle" select="$storedprocedurefirstColStyle"/>

       </xsl:call-template>

    </xsl:for-each>

    <xsl:for-each select="additionalInfo">

       <xsl:call-template name="entityadditionalInfo">

          <xsl:with-param name="entityfirstColStyle" select="$storedprocedurefirstColStyle"/>

       </xsl:call-template>

    </xsl:for-each>

    <!-- call physical moduel without show distribution(we want see it later)-->

    <xsl:if test="physical">

       <tr><td class="{$storedproceduresubHeaderStyle}" colspan="2">

        Physical Structure Description:

      </td></tr>

    </xsl:if>

    <xsl:for-each select="physical">

       <tr><td colspan="2">

        <xsl:call-template name="physical">

         <xsl:with-param name="physicalfirstColStyle" select="$storedprocedurefirstColStyle"/>

         <xsl:with-param name="notshowdistribution">yes</xsl:with-param>

        </xsl:call-template>

        </td></tr>

    </xsl:for-each>

    <!-- Here to display distribution info-->

    <xsl:for-each select="physical">

       <xsl:call-template name="storedProcedureShowDistribution">

          <xsl:with-param name="docid" select="$docid"/>

          <xsl:with-param name="entityindex" select="$entityindex"/>

          <xsl:with-param name="physicalindex" select="position()"/>

          <xsl:with-param name="storedprocedurefirstColStyle" select="$storedprocedurefirstColStyle"/>

          <xsl:with-param name="storedproceduresubHeaderStyle" select="$storedproceduresubHeaderStyle"/>

       </xsl:call-template>

    </xsl:for-each>

    <xsl:if test="coverage">

       <tr><td class="{$storedproceduresubHeaderStyle}" colspan="2">

        Coverage Description:

      </td></tr>

    </xsl:if>

    <xsl:for-each select="coverage">

      <tr><td colspan="2">

        <xsl:call-template name="coverage">

        </xsl:call-template>

      </td></tr>

    </xsl:for-each>

    <xsl:if test="method">

       <tr><td class="{$storedproceduresubHeaderStyle}" colspan="2">

        Method Description:

      </td></tr>

    </xsl:if>

    <xsl:for-each select="method">

      <tr><td colspan="2">

        <xsl:call-template name="method">

          <xsl:with-param name="methodfirstColStyle" select="$storedprocedurefirstColStyle"/>

          <xsl:with-param name="methodsubHeaderStyle" select="$storedproceduresubHeaderStyle"/>

        </xsl:call-template>

      </td></tr>

    </xsl:for-each>

    <xsl:if test="constraint">

       <tr><td class="{$storedproceduresubHeaderStyle}" colspan="2">

        Constraint:

      </td></tr>

    </xsl:if>

    <xsl:for-each select="constraint">

      <tr><td colspan="2">

        <xsl:call-template name="constraint">

          <xsl:with-param name="constraintfirstColStyle" select="$storedprocedurefirstColStyle"/>

        </xsl:call-template>

      </td></tr>

    </xsl:for-each>

    <xsl:for-each select="parameter">

       <tr><td width="{$firstColWidth}" class="{$storedprocedurefirstColStyle}">

            Parameter:

            </td>

            <td width="{$secondColWidth}">

               <table xsl:use-attribute-sets="cellspacing" class="{$tabledefaultStyle}">

                  <xsl:for-each select="name">

                    <tr><td width="{$firstColWidth}" class="{$storedprocedurefirstColStyle}">

                          Name:

                         </td>

                         <td width="{$secondColWidth}" class="{$secondColStyle}">

                           <xsl:value-of select="."/>

                         </td>

                     </tr>

                  </xsl:for-each>

                  <xsl:for-each select="domainDescription">

                    <tr><td width="{$firstColWidth}" class="{$storedprocedurefirstColStyle}">

                          Domain:

                         </td>

                         <td width="{$secondColWidth}" class="{$secondColStyle}">

                           <xsl:value-of select="."/>

                         </td>

                     </tr>

                  </xsl:for-each>

                  <xsl:for-each select="required">

                    <tr><td width="{$firstColWidth}" class="{$storedprocedurefirstColStyle}">

                          Required:

                         </td>

                         <td width="{$secondColWidth}" class="{$secondColStyle}">

                           <xsl:value-of select="."/>

                         </td>

                     </tr>

                  </xsl:for-each>

                  <xsl:for-each select="repeats">

                    <tr><td width="{$firstColWidth}" class="{$storedprocedurefirstColStyle}">

                         Repeatable:

                         </td>

                         <td width="{$secondColWidth}" class="{$secondColStyle}">

                           <xsl:value-of select="."/>

                         </td>

                     </tr>

                  </xsl:for-each>

               </table>

            </td>

       </tr>

    </xsl:for-each>

    <xsl:if test="$withAttributes='1' or $displaymodule='printall'">

    <xsl:for-each select="attributeList">

      <xsl:call-template name="storedProcedureAttributeList">

        <xsl:with-param name="storedprocedurefirstColStyle" select="$storedprocedurefirstColStyle"/>

        <xsl:with-param name="storedproceduresubHeaderStyle" select="$storedproceduresubHeaderStyle"/>

        <xsl:with-param name="docid" select="$docid"/>

        <xsl:with-param name="entityindex" select="$entityindex"/>

      </xsl:call-template>

    </xsl:for-each>

    </xsl:if>

  </xsl:template>

  <xsl:template name="storedProcedureShowDistribution">

     <xsl:param name="storedprocedurefirstColStyle"/>

     <xsl:param name="storedproceduresubHeaderStyle"/>

     <xsl:param name="docid"/>

     <xsl:param name="level">entitylevel</xsl:param>

     <xsl:param name="entitytype">storedProcedure</xsl:param>

     <xsl:param name="entityindex"/>

     <xsl:param name="physicalindex"/>

     <xsl:for-each select="distribution">

      <tr><td colspan="2">

        <xsl:call-template name="distribution">

          <xsl:with-param name="docid" select="$docid"/>

          <xsl:with-param name="level" select="$level"/>

          <xsl:with-param name="entitytype" select="$entitytype"/>

          <xsl:with-param name="entityindex" select="$entityindex"/>

          <xsl:with-param name="physicalindex" select="$physicalindex"/>

          <xsl:with-param name="distributionindex" select="position()"/>

          <xsl:with-param name="disfirstColStyle" select="$storedprocedurefirstColStyle"/>

          <xsl:with-param name="dissubHeaderStyle" select="$storedproceduresubHeaderStyle"/>

        </xsl:call-template>

      </td></tr>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="storedProcedureAttributeList">

    <xsl:param name="storedprocedurefirstColStyle"/>

    <xsl:param name="storedproceduresubHeaderStyle"/>

    <xsl:param name="docid"/>

    <xsl:param name="entitytype">storedProcedure</xsl:param>

    <xsl:param name="entityindex"/>

    <tr><td class="{$storedproceduresubHeaderStyle}" colspan="2">

        <xsl:text>Attribute(s) Info:</xsl:text>

    </td></tr>

    <tr><td colspan="2">

         <xsl:call-template name="attributelist">

           <xsl:with-param name="docid" select="$docid"/>

           <xsl:with-param name="entitytype" select="$entitytype"/>

           <xsl:with-param name="entityindex" select="$entityindex"/>

         </xsl:call-template>

       </td>

    </tr>

  </xsl:template>

</xsl:stylesheet>

<?xml version="1.0"?>

<!--

  *  '$RCSfile$'

  *      Authors: Matthew Brooke

  *    Copyright: 2000 Regents of the University of California and the

  *               National Center for Ecological Analysis and Synthesis

  *  For Details: http://www.nceas.ucsb.edu/

  *

  *   '$Author$'

  *     '$Date$'

  * '$Revision$'

  *

  * This program is free software; you can redistribute it and/or modify

  * it under the terms of the GNU General Public License as published by

  * the Free Software Foundation; either version 2 of the License, or

  * (at your option) any later version.

  *

  * This program is distributed in the hope that it will be useful,

  * but WITHOUT ANY WARRANTY; without even the implied warranty of

  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

  * GNU General Public License for more details.

  *

  * You should have received a copy of the GNU General Public License

  * along with this program; if not, write to the Free Software

  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA

  *

  * This is an XSLT (http://www.w3.org/TR/xslt) stylesheet designed to

  * convert an XML file that is valid with respect to the eml-variable.dtd

  * module of the Ecological Metadata Language (EML) into an HTML format

  * suitable for rendering with modern web browsers.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output method="html" encoding="iso-8859-1"

              doctype-public="-//W3C//DTD HTML 4.01 Transitional//EN"

              doctype-system="http://www.w3.org/TR/html4/loose.dtd"

              indent="yes" />  

   <xsl:template name="physical">

      <xsl:param name="docid"/>

      <xsl:param name="level">entity</xsl:param>

      <xsl:param name="entitytype"/>

      <xsl:param name="entityindex"/>

      <xsl:param name="physicalindex"/>

      <xsl:param name="distributionindex"/>

      <xsl:param name="physicalfirstColStyle"/>

      <xsl:param name="notshowdistribution"/>

      <table class="{$tabledefaultStyle}">

        <xsl:choose>

         <xsl:when test="references!=''">

          <xsl:variable name="ref_id" select="references"/>

          <xsl:variable name="references" select="$ids[@id=$ref_id]" />

          <xsl:for-each select="$references">

            <xsl:call-template name="physicalcommon">

              <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

              <xsl:with-param name="notshowdistribution" select="$notshowdistribution"/>

            </xsl:call-template>

          </xsl:for-each>

        </xsl:when>

        <xsl:otherwise>

          <xsl:call-template name="physicalcommon">

             <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

             <xsl:with-param name="notshowdistribution" select="$notshowdistribution"/>

          </xsl:call-template>

        </xsl:otherwise>

      </xsl:choose>

      </table>

  </xsl:template>

  <xsl:template name="physicalcommon">

    <xsl:param name="physicalfirstColStyle"/>

    <xsl:param name="notshowdistribution"/>

    <xsl:param name="docid"/>

    <xsl:param name="level">entity</xsl:param>

    <xsl:param name="entitytype"/>

    <xsl:param name="entityindex"/>

    <xsl:param name="physicalindex"/>

    <xsl:param name="distributionindex"/>

    <xsl:call-template name="physicalobjectName">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicalsize">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicalauthentication">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicalcompressionMethod">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicalencodingMethod">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicalcharacterEncoding">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicaltextFormat">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicalexternallyDefinedFormat">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:call-template name="physicalbinaryRasterFormat">

      <xsl:with-param name="physicalfirstColStyle" select="$physicalfirstColStyle"/>

    </xsl:call-template>

    <xsl:if test="$notshowdistribution=''">

      <xsl:for-each select="distribution">

        <xsl:call-template name="distribution">

          <xsl:with-param name="disfirstColStyle" select="$physicalfirstColStyle"/>

          <xsl:with-param name="dissubHeaderStyle" select="$subHeaderStyle"/>

          <xsl:with-param name="docid" select="$docid"/>

          <xsl:with-param name="level">entitylevel</xsl:with-param>

          <xsl:with-param name="entitytype" select="$entitytype"/>

          <xsl:with-param name="entityindex" select="$entityindex"/>

          <xsl:with-param name="physicalindex" select="$physicalindex"/>

          <xsl:with-param name="distributionindex" select="position()"/>

        </xsl:call-template>

      </xsl:for-each>

    </xsl:if>

  </xsl:template>

  <xsl:template name="physicalobjectName">

    <xsl:param name="physicalfirstColStyle"/>

    <xsl:for-each select="objectName">

      <tr>

        <td class="{$physicalfirstColStyle}">

        Object Name:</td>

        <td class="{$secondColStyle}">

        <xsl:value-of select="."/></td>

      </tr>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="physicalsize">

    <xsl:param name="physicalfirstColStyle"/>

    <xsl:for-each select="size">

      <tr>

        <td class="{$physicalfirstColStyle}">

        Size:</td>

        <td class="{$secondColStyle}">

        <xsl:value-of select="."/><xsl:text> </xsl:text><xsl:value-of select="./@unit"/></td>

      </tr>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="physicalauthentication">

    <xsl:param name="physicalfirstColStyle"/>

    <xsl:for-each select="authentication">

      <tr>

        <td class="{$physicalfirstColStyle}">

        Authentication:</td>

        <td class="{$secondColStyle}">

          <xsl:value-of select="."/><xsl:text> </xsl:text>

          <xsl:if test="./@method">

            Caculated By<xsl:text> </xsl:text><xsl:value-of select="./@method"/>

          </xsl:if>

        </td>

      </tr>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="physicalcompressionMethod">

    <xsl:param name="physicalfirstColStyle"/>

    <xsl:for-each select="compressionMethod">

      <tr>

        <td class="{$physicalfirstColStyle}">

        Compression Method:</td>

        <td class="{$secondColStyle}">

        <xsl:value-of select="."/></td>

      </tr>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="physicalencodingMethod">

    <xsl:param name="physicalfirstColStyle"/>

    <xsl:for-each select="encodingMethod">

      <tr>

        <td class="{$physicalfirstColStyle}">

        Encoding Method:</td>

        <td class="{$secondColStyle}">

        <xsl:value-of select="."/></td>

      </tr>

    </xsl:for-each>

  </xsl:template>

  <xsl:template name="physicalcharacterEncoding">

    <xsl:param name="physicalfirstColStyle"/>

    <xsl:for-each select="characterEncoding">

      <tr>

        <td class="{$physicalfirstColStyle}">

        Character Encoding:</td>

        <td class="{$secondColStyle}">

        <xsl:value-of select="."/></td>

      </tr>

    </xsl:for-each>

  </xsl:template>

  <!--***********************************************************

      TextFormat templates